4.12 Exercise 4.12

If we generalize lookup-variable-value, set-variable-value!, and define-variable! fully, we can see that the common pattern in each is that we loop through one frame in the environment, running one procedure if we find a binding with a given variable name, and running a different procedure if we reach the end of the current frame without finding it. In the case of lookup-variable-value and set-variable-value!, the latter procedure is the same iterative loop, but it doesn’t need to be so.

Based on the behaviors of these procedures, we can (somewhat arbitrarily) decide that the procedure executed if we find a binding should take the lists of variables and values as its parameters, and that the procedure to be performed if the frame doesn’t contain the binding we’re looking for only needs to take the current environment.

(define (search-env if-found if-not-found)
  (lambda (var env)
    (define (scan vars vals)
      (cond ((null? vars) (if-not-found env))
            ((eq? var (car vars)) (if-found vars vals))
            (else (scan (cdr vars) (cdr vals)))))
    (if (eq? env the-empty-environment)
        (error "Unbound variable" var)
        (let ((frame (first-frame env)))
          (scan (frame-variables frame)
                (frame-values frame))))))
(define (lookup-variable-value-alt val env)
  ((search-env
    (lambda (vars vals) (car vals))
    (lambda (env) (lookup-variable-value-alt val (enclosing-environment env))))
   val env))
(define (set-variable-value-alt! var val env)
  ((search-env
    (lambda (vars vals) (set-car! vals val))
    (lambda (env) (set-variable-value-alt! var val (enclosing-environment env))))
   var env))
(define (define-variable!-alt var val env)
  ((search-env
    (lambda (vars vals) (set-car! vals val))
    (lambda (env) (add-binding-to-frame! var val (first-frame env))))
   var env))

This arguably makes it clearer what the semantics of these procedures are – in particular, whether they search beyond the first frame of the environment or not.

← prev up next →

1	Chapter 1
2	Chapter 2
3	Chapter 3
4	Chapter 4
5	Chapter 5

4.1	Exercise 4.1
4.2	Exercise 4.2
4.3	Exercise 4.3
4.4	Exercise 4.4
4.5	Exercise 4.5
4.6	Exercise 4.6
4.7	Exercise 4.7
4.8	Exercise 4.8
4.9	Exercise 4.9
4.10	Exercise 4.10
4.11	Exercise 4.11
4.12	Exercise 4.12
4.13	Exercise 4.13
4.14	Exercise 4.14
4.15	Exercise 4.15
4.16	Exercise 4.16
4.17	Exercise 4.17
4.18	Exercise 4.18
4.19	Exercise 4.19
4.20	Exercise 4.20
4.21	Exercise 4.21
4.22	Exercise 4.22
4.23	Exercise 4.23
4.24	Exercise 4.24
4.25	Exercise 4.25
4.26	Exercise 4.26
4.27	Exercise 4.27
4.28	Exercise 4.28
4.29	Exercise 4.29
4.30	Exercise 4.30
4.31	Exercise 4.31
4.32	Exercise 4.32
4.33	Exercise 4.33
4.34	Exercise 4.34
4.35	Exercise 4.35
4.36	Exercise 4.36
4.37	Exercise 4.37
4.38	Exercise 4.38
4.39	Exercise 4.39
4.40	Exercise 4.40
4.41	Exercise 4.41
4.42	Exercise 4.42
4.43	Exercise 4.43
4.44	Exercise 4.44
4.45	Exercise 4.45
4.46	Exercise 4.46
4.47	Exercise 4.47
4.48	Exercise 4.48
4.49	Exercise 4.49
4.50	Exercise 4.50
4.51	Exercise 4.51
4.52	Exercise 4.52
4.53	Exercise 4.53
4.54	Exercise 4.54
4.55	Exercise 4.55
4.56	Exercise 4.56
4.57	Exercise 4.57
4.58	Exercise 4.58
4.59	Exercise 4.59
4.60	Exercise 4.60
4.61	Exercise 4.61
4.62	Exercise 4.62
4.63	Exercise 4.63
4.64	Exercise 4.64
4.65	Exercise 4.65
4.66	Exercise 4.66
4.67	Exercise 4.67
4.68	Exercise 4.68
4.69	Exercise 4.69
4.70	Exercise 4.70
4.71	Exercise 4.71